CAD开发者社区 › 首页 ›AutoCAD开发文档› AutoCAD 2022 开发者帮助 › 查看内容

AutoCAD 2022 开发者帮助

关于编辑填充图案（VBA/ActiveX）

2024-5-18 18:43| 发布者: admin| 查看: 94| 评论: 0|原作者: admin|来自: AutoCAD

您可以更改现有填充图案的角度或间距，也可以将其替换为实体填充或 AutoCAD 提供的预定义图案之一。

“边界填充线”（Boundary Hatch）对话框中的“图案”（Pattern）选项将显示这些图案的列表。为了减小文件大小，在图形中将填充定义为单个图形对象。

使用以下属性和方法来编辑填充图案：

图案角度: 指定填充图案的角度。
模式双倍: 指定用户定义的填充线是否为双剖面线。
模式名称: 指定填充图案名称（不更改图案类型）。
图案鳞片: 指定填充图案比例。
模式空间: 指定用户定义的填充图案间距。
设置模式: 设置填充的图案名称和图案类型。

更改图案填充的图案间距

本示例创建一个填充。然后，它将填充的当前图案间距增加 2。

Sub Ch4_ChangeHatchPatternSpace()
  Dim hatchObj As AcadHatch
  Dim patternName As String
  Dim PatternType As Long
  Dim bAssociativity As Boolean

  ' Define the hatch
  patternName = "ANSI31"
  PatternType = 0
  bAssociativity = True

  ' Create the associative Hatch object
  Set hatchObj = ThisDrawing.ModelSpace.AddHatch(PatternType, patternName, bAssociativity)

  ' Create the outer loop for the hatch.
  Dim outerLoop(0 To 0) As AcadEntity
  Dim center(0 To 2) As Double
  Dim radius As Double
  center(0) = 5
  center(1) = 3
  center(2) = 0
  radius = 3
  Set outerLoop(0) = ThisDrawing.ModelSpace.AddCircle(center, radius)
  hatchObj.AppendOuterLoop (outerLoop)
  hatchObj.Evaluate

  ' Change the spacing of the hatch pattern by
  ' adding 2 to the current spacing
  hatchObj.patternSpace = hatchObj.patternSpace + 2
  hatchObj.Evaluate
  ThisDrawing.Regen True
End Sub