创建对象反应器 （AutoLISP/ActiveX）

例

1. 在AutoCAD命令提示下，输入vlide。
2. 在 Visual LISP 中，单击“文件新建文件”。
3. 在新的 Visual LISP 文本编辑器窗口中，输入以下内容

   ; Define the callback function to use for the reactor
   ; The following function prints a message with the circle’s radius
   (defun print-radius (notifier-object reactor-object parameter-list)
     (vl-load-com)
     (cond
       (
        (vlax-property-available-p
          notifier-object
          "Radius"
        )
        (princ "The radius is ")
        (princ (vla-get-radius notifier-object))
       )
     )
   )
   
   ; Create a variable to hold the circle object that
   ; will be used as the owner of the reactor
   (setq myCircle
     ; Prompt for the center point and radius:
     (progn
       (setq ctrPt (getpoint "\nCircle center point: ")
                radius (distance ctrPt (getpoint ctrpt "\nRadius: "))
       )
   
       ; Add a circle to the drawing model space. Nest the function
       ; calls to obtain the path to the current drawing's model
       ; space: AcadObject > ActiveDocument > ModelSpace
       (vla-addCircle
         (vla-get-ModelSpace
           (vla-get-ActiveDocument (vlax-get-acad-object))
         )
         (vlax-3d-point ctrPt)
         radius
       )
     )
   )
   
   ; Create the reactor and pass it the circle object, 
   ; application-specific data, and callback function.
   (if (= circleReactor nil)
     (setq circleReactor (vlr-object-reactor (list myCircle)
       "Circle Reactor" '((:vlr-modified . print-radius))))
   )

4. 单击工具在编辑器中加载文本。
5. 在 AutoCAD 图形窗口中，指定圆的中心点和半径。
6. 创建圆后，选择它以显示其夹点。单击其中一个外部夹点以更改圆的半径。

   您应该在 STRETCH 选项的提示后看到类似于以下内容的消息：

   指定拉伸点或 [基点/复制/撤消/eXit]：半径为 3.75803